add iron and forge

2026-04-22 23:09:14 +03:00
parent 9066eecf1e
commit 297233c48e
10 changed files with 264 additions and 1 deletions
@@ -0,0 +1,134 @@
+extends CharacterBody3D
+
+const METAL_ARMOR_SCENE := preload("res://scenes/MetalArmor.tscn")
+
+signal destroyed
+
+enum State { IDLE, FLYING }
+
+const AIR_FRICTION  := 0.86
+const MIN_SPEED     := 0.5
+const WALL_BOUNCE   := 0.45
+const WALL_SELF_DMG := 0.5
+
+var kickable_type: String = "iron"
+var tier: int = 2
+var state: State = State.IDLE
+var fly_vel: Vector3 = Vector3.ZERO
+var health: float = 80.0
+var dead: bool = false
+var damage_modifier: float = 0.9
+
+@onready var mesh_node: MeshInstance3D = $IronMesh
+var iron_mat: StandardMaterial3D
+
+const COLOR_IDLE   := Color(0.55, 0.58, 0.62)
+const COLOR_IMPACT := Color(1.0, 1.0, 1.0)
+
+func _ready() -> void:
+	add_to_group("kickable")
+	iron_mat = mesh_node.material_override.duplicate() as StandardMaterial3D
+	mesh_node.material_override = iron_mat
+
+func apply_collision_damage(dmg: float) -> void:
+	_take_damage(dmg)
+
+func receive_kick(direction: Vector3, force: float) -> void:
+	fly_vel = direction * force
+	fly_vel.y = 0.0
+	state = State.FLYING
+
+func _physics_process(delta: float) -> void:
+	if state == State.IDLE:
+		return
+	_fly(delta)
+
+func _fly(delta: float) -> void:
+	var speed_now := Vector2(fly_vel.x, fly_vel.z).length()
+	velocity = fly_vel
+	velocity.y = 0.0
+	move_and_slide()
+
+	var handled := false
+	for i in get_slide_collision_count():
+		var col := get_slide_collision(i)
+		var col3d := col.get_collider() as Node3D
+		if col3d == null:
+			continue
+		if col3d.has_meta("is_forge"):
+			_hit_forge(col3d)
+			return
+		if col3d.has_meta("is_wall"):
+			var normal := col.get_normal()
+			normal.y = 0.0
+			if normal.length() > 0.01:
+				fly_vel = fly_vel.bounce(normal.normalized()) * WALL_BOUNCE
+			else:
+				fly_vel = Vector3.ZERO
+			_take_damage(speed_now * WALL_SELF_DMG)
+			handled = true
+			break
+		elif col3d.is_in_group("enemies") or col3d.is_in_group("kickable"):
+			if col3d == self:
+				continue
+			KickSystem.resolve(self, col3d, fly_vel)
+			if not dead and is_instance_valid(col3d):
+				var kick_dir := col3d.global_position - global_position
+				kick_dir.y = 0.0
+				if kick_dir.length() > 0.01:
+					col3d.call("receive_kick", kick_dir.normalized(), speed_now * 0.65)
+			fly_vel *= 0.45
+			handled = true
+			break
+
+	if not handled:
+		fly_vel = velocity
+		fly_vel.y = 0.0
+
+	fly_vel *= pow(AIR_FRICTION, delta * 60.0)
+
+	if Vector2(fly_vel.x, fly_vel.z).length() < MIN_SPEED:
+		fly_vel = Vector3.ZERO
+		velocity = Vector3.ZERO
+		state = State.IDLE
+
+	mesh_node.rotation.y += delta * speed_now * 0.3
+
+func _hit_forge(forge: Node3D) -> void:
+	if dead:
+		return
+	dead = true
+	state = State.IDLE
+	set_physics_process(false)
+	var parent := get_parent()
+	var spawn_pos := forge.global_position + Vector3(5, 0, 0)
+	queue_free()
+	if parent == null:
+		return
+	var armor := METAL_ARMOR_SCENE.instantiate() as Node3D
+	parent.add_child(armor)
+	armor.global_position = spawn_pos
+
+func _take_damage(dmg: float) -> void:
+	if dead:
+		return
+	health -= dmg
+	_flash()
+	if health <= 0.0:
+		_die()
+
+func _die() -> void:
+	dead = true
+	state = State.IDLE
+	set_physics_process(false)
+	emit_signal("destroyed")
+	var tw := create_tween()
+	tw.tween_property(self, "scale", Vector3(1.6, 0.1, 1.6), 0.12)
+	tw.tween_property(self, "scale", Vector3(0.0, 0.0, 0.0), 0.1)
+	tw.tween_callback(queue_free)
+
+func _flash() -> void:
+	var tw := create_tween()
+	tw.tween_property(iron_mat, "albedo_color", COLOR_IMPACT, 0.04)
+	var target_color := COLOR_IDLE.lerp(Color.RED, clampf(1.0 - health / 80.0, 0.0, 0.6))
+	tw.tween_property(iron_mat, "albedo_color", target_color, 0.18)